Excel funktionen AKTIEHISTORIK

Resumé

Excel funktionen AKTIEHISTORIK henter historiske aktiekursoplysninger baseret på et givet symbol og datointerval. Det primære formål med AKTIEHISTORIK er at få data om et finansielt instrument over tid. Resultatet er en række værdier, der overføres til regnearket i flere celler.

Formål

Hent aktiekursinformation

Returværdi

Array af aktiekursinformation

Syntaks

=AKTIEHISTORIK(stock; start_date, [end_date], [interval], [headers], [properties1], …)

Argumenter

stock (aktie) – Et ticker-symbol i dobbelte anførselstegn (“MSFT”, “AAPL”, “GOOG” osv.).

start_date (startdato) – startdatoen for data, der skal hentes.

end_date (slutdato) – [valgfrit] Slutdatoen for data, der skal hentes. Standard er startdato.

interval – [valgfrit] Tidsinterval. Daglig = 0, ugentlig = 1, månedlig = 2. Standard er 0.

headers (overskrifter) – [valgfrit] Ingen overskrift = 0, grundlæggende overskrift = 1, instrument + overskrift = 2. Standard er 1.

properties1 (egenskaber) – [valgfrit] Yderligere data kan hentes. Standard er Dato og Luk. Se nedenunder.

Noter

Funktionen henter historiske aktiekursoplysninger baseret på et givet symbol og datointerval. Hovedformålet med AKTIEHISTORIK er at få historien om et finansielt instrument over tid. Selvom navnet antyder, at AKTIEHISTORIK kun er beregnet til at fungere med aktier, kan AKTIEHISTORIK også arbejde med obligationer, indeksfonde, investeringsforeninger, obligationer og valutapar. AKTIEHISTORIK henter flere resultater. Resultatet er en række værdier, der overføres til regnearket i flere celler.

Funktionen AKTIEHISTORIK accepterer fem primære argumenter og yderligere seks egenskabsargumenter til at hente yderligere information. Stock og start_date er de eneste påkrævede argumenter. Hvert argument er beskrevet i detaljer nedenfor. Yderligere egenskaber er beskrevet længere nede i artiklen.

Bemærk

Den sikreste måde at angive startdato og slutdato på er som en reference til en celle, der indeholder en gyldig dato, eller med funktionen DATO. Dette skyldes, at datoer, der indtastes som tekstværdier, nogle gange kan misfortolkes.

Primære argumenter

Stock – ticker-symbolet, der bruges til at hente historiske priser. Stock skal angives som en tekstværdi i dobbelte anførselstegn (“”), når det er hardkodet, for eksempel ”ISS”, ”JDAN”, ”JYSK”, ”KBHL” og ”MAERSK A” osv. Resultater hentes fra standardudvekslingen for instrumentet. For at anmode om oplysninger fra en specifik børs skal du foran symbolet have en 4-tegns ISO-markedsidentifikationskode (MIC), efterfulgt af et kolon. For for eksempel at henvise til Carlsberg A på børsen Nasdaq Copenhagen, skal du bruge “XCSE:CARL A”. For at henvise til Microsoft Corporation på Østrigs Wiener Boerse-børs, brug “XWBO:MSFT”.

Start_date – Den dato, hvor man begynder at hente data. Bemærk, at start_date ikke nødvendigvis er den første dato, der vises i resultaterne. Hvis interval er sat til daglig (0), vil den første dato i resultaterne være den første dato, hvor udvekslingen er åben, og data er tilgængelige. Hvis interval er sat til ugentlig (1) eller månedlig (2), vil den første dato blive sat til den første dato i perioden, dvs. den første dag i ugen eller den første dag i måneden.

End_date – Den dato, hvor man stopper med at hente data. Ligesom start_date kan den faktiske sidste dato i resultater afvige fra den angivne slutdato. Hvis interval er indstillet til daglig (0), vil den sidste dato i resultaterne være den sidste dato i det datointerval, hvor data er tilgængelige. Hvis interval er sat til ugentlig (1) eller månedlig (2), vil den sidste dato være den sidste dato i perioden, dvs. sidste dag i ugen eller sidste dag i måneden. Slutdato er valgfri og vil som standard være startdato, hvis den ikke er angivet.

Interval – tidsrummet mellem datapunkter. De tilgængelige indstillinger er Daglig (0), Ugentlig (1) og Månedlig (2). Interval er valgfrit og vil som standard være Dagligt (0), hvis det ikke er angivet.

Headers – argumentet headers– styrer overskrift-informationen, der vises øverst i de hentede data. De tilgængelige muligheder er Ingen overskrift (0), Grundlæggende overskrift (1) og overskrift med instrumentoplysninger (2). Overskrifter er valgfri og vil som standard være standardoverskrifter (1), når de ikke er angivet.

PropertiesProperties1 – Properties5 repræsenterer yderligere information, der kan hentes. Se tabellen nedenfor for detaljer.

Egenskaber

Tabellen nedenfor viser den yderligere information, funktionen AKTIEHISTORIK kan hente, som beskrives som egenskaber. Egenskaber er angivet med den numeriske kode, der ses i kolonnen “Kode”, og kan vises i vilkårlig rækkefølge. Bemærk, at AKTIEHISTORIK som standard vil hente Dato og Luk.

KodeVærdiBeskrivelse
0DatoFørste handelsdag i perioden
1SlutSlutkurs sidste handelsdag i perioden
2ÅbenÅbningskurs på sidste handelsdag i perioden
3HøjHøjeste pris i perioden
4LavLaveste pris i perioden
5VolumenOmsat volumen i perioden

Eksempel 1 – Daglige resultater

For at hente den daglige lukkepris for Carlsberg A (“CARL A”) for marts måned 2022 er formlen i celle A1:

=AKTIEHISTORIK("XCSE:CARL A";DATO(2022;3;1);DATO(2022;3;31))

Interval er ikke angivet og standard er Dagligt (0). Headers er ikke angivet og standard er Dato og Slut. Med denne konfiguration returnerer funktionen AKTIEHISTORIK 23 resultater. Bemærk, at weekender er udelukket, og den første dato, der hentes, er 1. marts. Bemærk også, at funktionen DATO bruges til at angive start- og slutdatoer.

Eksempel 2 – variable input

I eksemplet nedenfor er input for stock, start_date og end_date gjort variable ved at placere dem i regnearket i cellerne E1, E2 og E3. Formlen i celle A1 er:

=AKTIEHISTORIK(E1;E2;E3;2)

Bemærk, at det fjerde argument, interval, er sat til 2, som udsender månedlige resultater.

Resultatet er lukkeprisen for BAVARIAN (“BAVA”) for 6 måneder i 2021. Hvis værdierne i E1:E3 ændres, vil resultaterne fra AKTIEHISTORIK automatisk opdateres.

Eksempel 3 – yderligere egenskaber

De egenskaber, der returneres af AKTIEHISTORIK, kan kontrolleres ved at tilpasse og/eller omarrangere tal, der starter med det sjette argument (properties1). I eksemplet vist nedenfor er formlen i celle A1:

=AKTIEHISTORIK(H1;H2;H3;2;1;0;5;3;4;1)

Resultatet er månedlige aktiekursoplysninger for Danske Bank (“DANSKE”) for 7 måneder i 2022. De ønskede egenskaber inkluderer Dato (0), Omsætning (5), Højeste (3), Laveste (4) og Slut (1). Bemærk, at dette er de sidste 5 argumenter i funktionen.

Eksempel 4 – vandret layout

Som standard returnerer AKTIEHISTORIK oplysninger i et lodret layout. For at vise resultater i et vandret layout kan du bruge funktionen TRANSPONER. I eksemplet vist nedenfor er formlen i A1, kopieret ned,

=TRANSPONER(AKTIEHISTORIK(B2;EDATO(IDAG();-5);IDAG();2;0;1))

Resultatet er den efterfølgende månedlige lukkepris for hver aktie i de seneste 6 måneder.

Funktionen EDATE og funktionen IDAG bruges til at oprette en startdato 5 måneder tilbage i fortiden. Slutdatoen er den aktuelle dato, forsynet med funktionen IDAG.

Eksempel 5 – variabel udveksling

For at anmode om oplysninger fra en specifik børs, skal du foran symbolet have en kode på 4 tegn efterfulgt af et kolon (:). I regnearket nedenfor er udvekslingen variabel og indtastet i celle E1. Formlen i celle A1 er:

=AKTIEHISTORIK(E1&":"&E2;E3;E4;2)

Resultatet er den månedlige lukkekurs for BMW på Deutsche Boerse:

Hvis værdien i E1 ændres til “XETR”, vil AKTIEHISTORIK returnere den månedlige lukkekurs for BMW på Xetra børsen.

Eksempel 6 – valutakurs

For at få valutakursen for et givet valutapar med AKTIEHISTORIK skal du indtaste de to 3-bogstavskoder adskilt af et kolon (:) som aktieargument. For at få den månedlige valutakurs mellem danske kroner (“DKK”) og Euro (“EUR”) for månederne januar 2021 til december 2021 kan du f.eks. bruge AKTIEHISTORIK på denne måde:

=AKTIEHISTORIK("EUR:DKK";DATO(2021;1;1);DATO(2021;12;1);2)

Resultatet er et array med tolv måneders kurser:

For at vende retningen af udvekslingen skal du bare bytte rækkefølgen af valutaparrene:

=AKTIEHISTORIK("DKK:EUR";DATO(2021;1;1);DATO(2021;12;1);2)

Noter

  • Hvis data ikke er tilgængelige for den anmodede periode, returnerer AKTIEHISTORIK en #VÆRDI! fejl.
  • Når intervallet er månedligt (2), returnerer AKTIEHISTORIK de seneste data i en given måned.

Skriv et svar

Din e-mailadresse vil ikke blive publiceret. Krævede felter er markeret med *

nineteen − 2 =