Udtræk tegn fra en streng

Excel brugere har ofte brug for at udtrække tegn fra en streng. For eksempel har du en liste med ansattes navne (for og efternavne) og har brug for at udtrække efternavnet fra hver celle. Excel har flere nyttige funktioner der udtrækker tegn:

  • VENSTRE: Returnere et specifikt antal tegn fra begyndelsen af strengen
  • HØJRE: Returnere et specifikt antal tegn fra slutningen af strengen
  • MIDT: Returnere et specifikt antal tegn fra en specificeret placering i strengen

Formlen der følger returnere de sidste ti tegn fra celle A1. hvis A1 indeholder mindre end ti tegn, vil formlen returnere hele teksten i cellen.

=HØJRE(A1,10)

Den næste formel benytter funktionen MIDT til at returnere fem tegn fra celle A1, og begynder ved tegnplacering 2. Med andre ord, returnerer den tegnene 2 til 6.

=MIDT(A1,2,5)

Det følgende eksempel returnerer teksten i celle A1, med kun det første bogstav med stort. Den bruger funktionen VENSTRE til at udtrække det første tegn og konvertere det til stort bogstav. Dette tegn sammenkædes til en anden streng, der gør brug af funktionen HØJRE til at udtrække alle tegn på nær det første (konverteret til små bogstaver).

=STORE.BOGSTAVER(VENSTRE(A1))&SMÅ.BOGSTAVER(HØJRE(A1;LÆNGDE(A1)-1))

Hvis celle A1 indeholder tekste FØRSTE KVARTAL, vil formlen returnere Første kvartal.

Erstat tekst med en anden tekst

I visse situationer kan du have brug for en formel, der erstatter en del af en tekststreng med en anden tekst. For eksempel kan du importere data, der indeholder stjerne tegn (*), og du skal konvertere stjernen til et andet tegn. Du kunne bruges Excels Hjem -> Rediger -> Søg og vælg -> Erstat for at foretage erstatningen. Hvis du foretrækker en formelbaseret løsning, kan du med fordel benytte to funktioner:

  • UDSKIFT: erstatter specifik tekst i en streng. Benyt denne funktion når du ved hvilke tegn du vil erstatte og ikke positionen.
  • ERSTAT: erstatter tekst der optræde på en bestemt placering i en streng. Benyt denne funktion når du kender positionen på teksten du vil erstatte men ikke den præcise tekst.

Den følgende formel benytter funktionen UDSKIFT til at erstatte 2016 med 2017 i stregen Budget for 2016. formlen returnere Budget for 2017.

=UDSKIFT("Budget for 2016";"2016";"2017")

Følgende formel benytter funktionen UDSKIFT til at fjerne alle mellemrum i en streng. Med andre ord så erstatter den alle mellemrumstegn med en tom streng. Formlen returnere Budgetfor2017.

=UDSKIFT("Budget for 2017";" ";"")

Den følgende funktion benytter funktionen ERSTAT til at erstatte et tegn på position 4 med ingen ting. Med andre ord så fjerne den det femte tegn (en bindestreg) og returnere Del44.

=ERSTAT("Del-44";4;1;"")

Du kan selvfølgelig indlejre disse funktioner, så de udfører flere erstatninger i en enkelt formel. Formlen der følger demonstrerer kraften i indlejret UDSKIFT funktioner. I bund og grund udraderer formlen enhver forekomst af følgende syv tegn i celle A1: mellerum, bindestreg, kolon, stjerne, underscore, vestre parentes og højre parentes.

=UDSKIFT(UDSKIFT(UDSKIFT(UDSKIFT(UDSKIFT(UDSKIFT(UDSKIFT(A1;"
";"");"-";"");":";"");"*";"");"_";"");"(";"");")";"")

Hvis celle A1 indeholder strengen Del-2a_B (3MU)A*, vil formlen returnere Del2aB3MUA.

Find og søg i en streng

Excel funktionerne FIND og SØG giver dig mulighed for at finde startpositionen på en bestemt delstreng i en streng:

  • FIND: Finder en delstreng i en anden tekststreng og returnerer startpositionen på delstrengen. Du kan specificere tegnpositionen, hvor søgningen skal begynde. Brug denne funktion til versalfølsom tekst sammenligning. Sammenligning med jokertegn understøttes ikke.
  • SØG: Finder en delstreng i en anden tekststreng og returner startpositionen på delstrengen. Du kan specificere tegnpositionen, hvor søgningen skal begynde. Brug denne funktion til ikke versalfølsom tekst og når du har brug for jokertegn.

Den følgende formel bruger funktionen FIND og returnerer 10, positionen på det første m i strengen. Bemærk denne formel er versalfølsom.

=FIND("m";"Peter Malm Jensen";1)

Formlen der følger, bruger funktionen SØG, og returnere 7, positionen på det første m (enten småbogstaver eller storebogstaver):

 =SØG("m";"Peter Malm Jensen";1)

Du kan bruge følgende jokertegn i det første argument i funktionen SØG:

  • Spørgsmålstegn (?): Matcher ethvert enkelt tegn
  • Stjerne (*): Matcher enhver sekvens af tegn

Hvis du rent faktisk vil finde et spørgsmålstegn eller en stjerne tegn, skal du skrive tilde (~) før spørgsmålstegnet eller stjernen. Hvis du vil finde en tilde, skriver du to tilder.

Den næste formel undersøger teksten i celle A1, og returnerer positionen på den første position af tre-tegn sekvensen der har en bindestreg i midten. Med andre ord ser den efter ethvert tegn efterfulgt af en bindestreg og endnu et tegn. Hvis celle A1 indeholder Del-B15, vil formlen returnere 3.

=SØG("?-?";A1;1)

Søg og erstat i en streng

Du kan bruge funktionen ERTSTAT sammenholdt med funktionen SØG til at oprette en ny streng, der erstatter en del af den originale tekststreng med en anden streng. I virkeligheden kan du bruge funktionen SØG til at finde startplaceringen til brug af funktionen ERSTAT.

Antag For eksempel at celle A1 indeholder teksten Den årlige indtægt. Den følgende formel søger efter ordet årlige og erstatter de seks tegn med ordet månedlige:

=ERSTAT(A1;SØG("årlige";A1);6;"månedlige")

Den næste formel bruger funktionen UDSKIFT til at løse den samme opgave på en mere effektiv måde:

=UDSKIFT(A1;"årlige";"månedlige")

Du kan eventuelt også få udbytte af denne artikel: UDTRÆK FORNAVNE, MELLEMNAVNE OG EFTERNAVNE

Bo Jönsson

Skriv et svar

Din e-mailadresse vil ikke blive publiceret. Krævede felter er markeret med *

3 + nineteen =